Перегляд вихідного коду сторінки Крива Коха

[[Файл:Fractal koch.png|200px|thumb|right|Крива Коха]]
[[Файл:KochSnowGif16 800x500 2.gif|200px|thumb|right|Збільшення сніжинки Коха]]
{{unibox}}'''Крива́ Ко́ха'''&nbsp;— [[фрактал]]ьна [[крива]], описана [[1904]] року шведським математиком [[Хельге фон Кох]]ом<ref name=slyusarantenna1>Слюсар В.&nbsp;И.&nbsp;[http://slyusar.kiev.ua/ra0209_SLYUSAR.pdf Фрактальные антенны] {{Webarchive|url=https://web.archive.org/web/20180219132336/http://www.slyusar.kiev.ua/ra0209_SLYUSAR.pdf |date=19 лютого 2018 }}.// Радиоаматор.&nbsp;— 2002.&nbsp;— №&nbsp;9.&nbsp;— С. 54 -56., Конструктор.&nbsp;— 2002.&nbsp;— №&nbsp;8.&nbsp;— С. 6&nbsp;— 8.</ref><ref name="wireless">Вишневский В. М., Ляхов А. И., Портной С. Л., Шахнович И. В. Широкополосные беспроводные сети передачи информации. — М.: Техносфера. — 2005.- C. 498—569</ref>.

Крива Коха цікава тим, що ніде не має [[дотична|дотичних]], тобто ніде не [[диференційовність|диференційовна]], хоча всюди [[Неперервна функція|неперервна]].

Три копії кривої Коха, побудовані (вістрями назовні) на сторонах [[правильний трикутник|правильного трикутника]], утворюють замкнену криву, так звану ''сніжинку Коха''<ref name=slyusarantenna1/><ref name=slyusarantenna2>{{cite web
 |last         = Слюсар
 |first        = В.
 |title        = Фрактальные антенны. Принципиально новый тип «ломаных» антенн.
 |work         = Электроника: наука, технология, бизнес. — 2007. — № 5.
 |date         = 2007
 |pages        = С. 78—83.
 |url          = http://www.electronics.ru/files/article_pdf/0/article_593_229.pdf
 |accessdate   = 6 травня 2020
 |archive-date = 28 березня 2018
 |archive-url  = https://web.archive.org/web/20180328174319/http://www.electronics.ru/files/article_pdf/0/article_593_229.pdf
}}</ref><ref name="wireless" />.
Крива Коха задається такою системою ітераційних функцій:

: <math>f1(z)=(1/3)*z;</math>
: <math>f2(z)=(1/3)*z+(2/3);</math>
: <math>f3(z)=(1/3)*z(cos(pi/3)+i*sin(pi/3))+(1/3);</math>

== Побудова ==
{{Без джерел|розділ|дата=травень 2020}}
Крива Коха є типовим геометричним [[фрактал]]ом. Процес її побудови виглядає так: беремо одиничний відрізок, поділяємо на три рівні частини і замінюємо середній інтервал рівностороннім трикутником без цього сегмента. У результаті утворюється ламана, що складається з чотирьох ланок з довжиною 1/3 довжини початкового відрізка. На наступному кроці повторюємо операцію для кожного з чотирьох отриманих ланок і так далі. Гранична крива і є кривою Коха.

{{Hider|
  title = Приклад скрипту ([[PHP]]) |
  hidden = 1 |
  title-style = text-align: left; |
  content-style = text-align: left; |
  content =
<syntaxhighlight lang="php">
<?php
	set_time_limit(3);

	$x = 600;	// Довжина малюнку
	$y = 200;	// Висота малюнку
	$r = 10;	// Рамка
	$i = 4;		// Кількість ітерацій

	define("PI", 3.14159265358979323846);

	$img = imagecreate($x, $y);
	$black = imagecolorallocate($img, 0, 0, 0);
	imagefill($img, 1, 1, $black);
	$color = imagecolorallocate($img, 255, 255, 255);

	recursion($i, $r, $y - $r, $x - $r, $y - $r);
	function recursion($i, $x1, $y1, $x2, $y2) {
		global $img, $color;

		if($i == 0)
			imageline($img, $x1, $y1, $x2, $y2, $color);

		else {
			$alpha = atan2($y2 - $y1, $x2 - $x1);
			$r = sqrt(($x2 - $x1) * ($x2 - $x1) + ($y2 - $y1) * ($y2 - $y1));

			$xa = $x1 + $r * cos($alpha) / 3;
			$ya = $y1 + $r * sin($alpha) / 3;

			$xc = $xa + $r * cos($alpha - PI / 3) / 3;
			$yc = $ya + $r * sin($alpha - PI / 3) / 3;

			$xb = $x1 + 2 * $r * cos($alpha) / 3;
			$yb = $y1 + 2 * $r * sin($alpha) / 3;

			recursion($i - 1, $x1, $y1, $xa, $ya);
			recursion($i - 1, $xa, $ya, $xc, $yc);
			recursion($i - 1, $xc, $yc, $xb, $yb);
			recursion($i - 1, $xb, $yb, $x2, $y2);
		}
	}

	header("Content-type: image/png");
	imagepng($img);
	imagedestroy($img);
?>
</syntaxhighlight>
}}

{{Hider|
  title = Крива Коха за допомогою рекурсії. Приклад коду на ([[Processing]]) |
  hidden = 1 |
  title-style = text-align: left; |
  content-style = text-align: left; |
  content =
<syntaxhighlight lang="java">
int i = 0; // Кількість ітерацій 

void setup()
{
  size(600, 250); // Розміри вікна
}

void draw()
{
  // замалювати все в чорний корлі
  background(0);
  
  // відобразити білим кольором номер ітерації в лівому верхньому куті
  stroke(255);
  text(i, 10, 20);

  // намалювати Криву Коха за допомогою рекурсивних викликів
  recursion(i, 0, 200, 600, 200 );
}

void recursion(int i, float x1, float y1, float x2, float y2)
{
  // кінець рекурсивним викликам функції
  if (i == 0) 
  {
    // намалювати білу лінію від точки (x1, y1) до (x2, y2)
    stroke(255);
    line(x1, y1, x2, y2);
    return;
  }

  float alpha = atan2(y2 - y1, x2 - x1);// кут повороту
  float r = sqrt((x2 - x1) * (x2 - x1) + (y2 - y1) * (y2 - y1));// відстань між точками

  // обраховує 3 точки на прямій
  //       C
  //      / \
  // ----A   B----
  // ліва точка (ліва вершина трикутника)
  float xa = x1 + r * cos(alpha) / 3;
  float ya = y1 + r * sin(alpha) / 3;

  // центральна точка (верхня вершина трикутника)
  float xc = xa + r * cos(alpha - PI / 3) / 3;
  float yc = ya + r * sin(alpha - PI / 3) / 3;

  // права точка (права вершина трикутника)
  float xb = x1 + 2 * r * cos(alpha) / 3;
  float yb = y1 + 2 * r * sin(alpha) / 3;

  // рекурсивні виклики функції для 4 отриманих ліній
  recursion(i - 1, x1, y1, xa, ya);
  recursion(i - 1, xa, ya, xc, yc);
  recursion(i - 1, xc, yc, xb, yb);
  recursion(i - 1, xb, yb, x2, y2);
}
// перехід на наступну ітерації із нажиманням клавіші мишки
void mousePressed()
{
  ++i;
}
</syntaxhighlight>
}}

{{Hider|
  title = Сніжинка Коха. Приклад коду на ([[Processing]]) |
  hidden = 1 |
  title-style = text-align: left; |
  content-style = text-align: left; |
  content =
<syntaxhighlight lang="java">
// клас є одніє лінією, яка вміє генерувати на собі Криву Коха
class Segment
{
  // поля
  PVector start; // початок лінії
  PVector end; // кінець лінії
  // конструктор
  Segment(PVector start, PVector end)
  {
    this.start = start.copy();
    this.end = end.copy();
  }
  // методи
  // генеруємо Криву Коха на прямій
  Segment[] generate()
  {        
    // з одної прямою утворюється 4
    Segment[] children = new Segment[4];
    
    // 1/3 прямої
    PVector v = PVector.sub(end, start);
    v.div(3);
    
    // ліва вершина трикутника
    PVector ls = PVector.add(start, v);
    children[0] = new Segment(start, ls);
    
    // права вершина трикутника
    PVector rs = PVector.sub(end, v);
    children[3] = new Segment(rs, end);
    
    // верхня вершина трикутника
    v.rotate(-PI/3);
    PVector m = PVector.add(ls, v);
    children[1] = new Segment(ls, m);
    children[2] = new Segment(m, rs);
    
    // повертаємо Криву Коха для цієї лінії
    return children;
  }
  // відображаємо лінію
  void show()
  {
    stroke(255);
    line(start.x, start.y, end.x, end.y);
  }
}
// динамічний масив кривих, які будуть відображатись
ArrayList<Segment> segments;
int i;// номер ітерації

void setup()
{
  size(600, 600);// розмір вікна
  // ініціалізація полів
  segments = new ArrayList<Segment> ();
  i = 0;
  
  // встановлюємо 3 точки, вершини трикутника
  PVector leftPoint = new PVector(100, 200);
  PVector rightPoint = new PVector(500, 200);
  PVector bottomPoint = new PVector(300, 500);
  
  // зєднюємо ці точки прямими
  Segment s1 = new Segment(bottomPoint, leftPoint);
  Segment s2 = new Segment(leftPoint, rightPoint);
  Segment s3 = new Segment(rightPoint, bottomPoint);
  
  // додаємо ці прямі до масиву
  segments.add(s1);
  segments.add(s2);
  segments.add(s3);
}

void draw()
{
  // замалювати все в чорний колір
  background(0);
  
  // відобразити білим кольором номер ітерації в лівому верхньому куті
  fill(255);
  text(i, 10, 20);
  
  // відобразити усі прямі
  for (Segment segment : segments)
  {
    segment.show();
  }
}
// з нажиманням клавіші миші, обраховуємо прямі в наступній ітерації
void mousePressed()
{
  // тимчасовий динамічний масив для нових прямих
  ArrayList<Segment> nextGeneration = new ArrayList<Segment>(segments.size() * 4);
  // для кожної прямої із минулої ітерації...
  for (Segment segment: segments)
  {
    // ... обраховуємо Криву Коха
    Segment[] child = segment.generate();
    // усі прямі Кривої Коха запам'ятовуємо в тимчасовий масив
    for (Segment c : child)  nextGeneration.add(c);
  }
  // тимчасовий масив стає постійним, про масив на минулій ітерації забуваємо
  segments = nextGeneration;
  // збільшуємо номер ітерації
  ++i;
}
</syntaxhighlight>
}}

== Властивості ==
* Крива Коха ніде не [[Диференційовність|диференційована]] і не [[Спрямність|спрямна]].
* Крива Коха не має самоперетинів.
* Крива Коха має проміжну (тобто не [[ціле число|цілу]]) [[розмірність Хаусдорфа]], яка дорівнює <math>\ln4/\ln3\approx 1,26</math>, оскільки вона складається з чотирьох рівних частин, кожна з яких подібна всій кривій з коефіцієнтом [[подібність|подібності]] 1/3.
* Довжина кривої Коха описується виразом 
: <math>P_n = s \cdot \left(\frac{4}{3} \right)^n,</math> де <math>n</math>&nbsp;— кількість ітерацій, <math>s</math>&nbsp;— довжина початкового [[відрізок|відрізка]]<ref name=slyusarantenna2 />.

== Узагальнення ==
[[Файл:Von Koch curve.gif|thumb|300px|Перші сім [[ітерація|ітерацій]] побудови сніжинки Коха]]
Можливі узагальнення кривої Коха, також використовують при побудові підставлення [[ламана|ламаної]] з чотирьох рівних відрізків, але вони мають іншу геометрію. Вони мають Розмірність Хаусдорфа від 1 до 2. Зокрема, якщо замість поділу відрізка 1:1:1 використовувати [[золотий перетин]] (φ: 1: φ), то отримаємо криву, що має відношення до [[Мозаїка Пенроуза|мозаїк Пенроуза]].

Також можна побудувати криву «Хрест Коха» на сторонах [[квадрат]]а, при цьому проводячи побудову «в середину» квадрата.

Також можна побудувати «Сніжинку Коха» на сторонах рівностороннього [[трикутник]]а.

== Див. також ==
* [[Крива Гільберта]]
* [[Крива Мура]]
* [[Крива Мінковського]]

== Примітки ==
{{reflist}}

== Джерела ==
* Вишневский В. М., Ляхов А. И., Портной С. Л., Шахнович И. В. Широкополосные беспроводные сети передачи информации. — М.: Техносфера. — 2005.- C. 498—569.

== Посилання ==
* [http://mathworld.wolfram.com/KochSnowflake.html Сніжинка Коха на вебсайті «Wolfram Mathworld»] {{Webarchive|url=https://web.archive.org/web/20200807160024/https://mathworld.wolfram.com/KochSnowflake.html |date=7 серпня 2020 }}

{{Commons|Koch snowflake}}
{{Фрактали}}
{{Криві}}
{{math-stub}}

[[Категорія:Фрактальні криві]]
[[Категорія:Статті з прикладами коду мовою Java]]
[[Категорія:Статті з прикладами коду мовою PHP]]